The formula of the Select Case statement is: Select Case Expression Case Expression1 Statement1 Case Expression2 Statement2 Case ExpressionX StatementX End Select The statement starts with Select Case and ends with End Select. On the right side of Select Case, enter a value, the Expression factor, that will be used as a tag. The value of Expression can be Boolean value (a Boolean type), a character (Char type), a string (a String type), a natural number (a Byte, an SByte, a Short, a UShort, an Integer, a UInteger, a Long, or a ULong type), a decimal number (a Single, a Double, or a Decimal type), a date or time value (a Date type), an enumeration (an Enum type), or else (an Object type). Inside the Select Case and the End Select lines, you provide one or more sections that each contains a Case keyword followed by a value. The value on the right side of Case, ExpresionX, must be the same type as the value of Expression or it can be implied from it. After the case and its expression, you can write a statement. When this section of code is accessed, the value of Expression is considered. Then the value of Expression is compared to each ExpressionX of each case:
Here is an example: Module Exercise
Public Function Main() As Integer
Dim Answer As Byte
Answer = CByte(InputBox( _
"One of the following is not a Visual Basic keyword" & vbCrLf &
"1) Function" & vbCrLf &
"2) Except" & vbCrLf &
"3) ByRef" & vbCrLf &
"4) Each" & vbCrLf & vbCrLf &
"Your Answer? "))
Select Case Answer
Case 1
MsgBox("Wrong: Function is a Visual Basic keyword." & vbCrLf &
"It is used to create a procedure of a function type")
Case 2
MsgBox("Correct: Except is not a keyword in " & vbCrLf &
"Visual Basic but __except is a C++ " & vbCrLf &
"keyword used in Exception Handling")
Case 3
MsgBox("Wrong: ByRef is a Visual Basic keyword used " & vbCrLf &
"to pass an argument by reference to a procedure")
Case 4
MsgBox("Wrong: The ""Each"" keyword is used in " & vbCrLf &
"Visual Basic in a type of looping " & vbCrLf &
"used to ""scan"" a list of item.")
End Select
Return 0
End Function
End Module
Here is an example of running the program:
The above code supposes that one of the cases will match the value of the Expression factor. This is not always so. If you anticipate that there could be no match between the Expression and one of the Expressions, you can use a Case Else statement at the end of the list. The statement would then look like this: Select Case Expression Case Expression1 Statement1 Case Expression2 Statement2 Case Expressionk Statementk Case Else Statementk End Select In this case, the statement after the Case Else will execute if none of the previous expressions matches the Expression factor. Here is an example: Module Exercise
Public Function Main() As Integer
Dim Answer As Byte
Answer = CByte(InputBox( _
"One of the following is not a Visual Basic keyword" & vbCrLf &
"1) Function" & vbCrLf &
"2) Except" & vbCrLf &
"3) ByRef" & vbCrLf &
"4) Each" & vbCrLf & vbCrLf &
"Your Answer? "))
Select Case Answer
Case 1
MsgBox("Wrong: Function is a Visual Basic keyword." & vbCrLf &
"It is used to create a procedure of a function type")
Case 2
MsgBox("Correct: Except is not a keyword in " & vbCrLf &
"Visual Basic but __except is a C++ " & vbCrLf &
"keyword used in Exception Handling")
Case 3
MsgBox("Wrong: ByRef is a Visual Basic keyword used " & vbCrLf &
"to pass an argument by reference to a procedure")
Case 4
MsgBox("Wrong: The ""Each"" keyword is used in " & vbCrLf &
"Visual Basic in a type of looping " & vbCrLf &
"used to ""scan"" a list of item.")
Case Else
MsgBox("Invalid Selection")
End Select
Return 0
End Function
End Module
Here is an example of running the program:
As mentioned in our introduction, the Select Case can use a value other than an integer. For example you can use a character. Here is an example: Module Exercise
Public Function Main() As Integer
Dim Gender As Char
Gender = "M"
Select Case Gender
Case "F"
MsgBox("Female")
Case "M"
MsgBox("Male")
Case Else
MsgBox("Unknown")
End Select
Return 0
End Function
End Module
This would produce:
Notice that in this case we are using only upper case characters. If want to validate lower case characters also, we may have to create additional case sections for each. Here is an example: Module Exercise
Public Function Main() As Integer
Dim Gender As Char
Gender = "f"
Select Case Gender
Case "f"
MsgBox("Female")
Case "F"
MsgBox("Female")
Case "m"
MsgBox("Male")
Case "M"
MsgBox("Male")
Case Else
MsgBox("Unknown")
End Select
Return 0
End Function
End Module
This would produce:
Instead of using one value for a case, you can apply more than one. To do this, on the right side of the Case keyword, you can separate the expressions with commas. Here are examples: Module Exercise
Public Function Main() As Integer
Dim Gender As Char
Gender = "F"
Select Case Gender
Case "f", "F"
MsgBox("Female")
Case "m", "M"
MsgBox("Male")
Case Else
MsgBox("Unknown")
End Select
Return 0
End Function
End Module
You can use a range of values for a case. To do this, on the right side of Case, enter the lower value, followed by To, followed by the higher value. Here is an example: Imports System
Module Exercise
Public Function Main() As Integer
Dim Age As Integer
Age = 24
Select Case Age
Case 0 To 17
MsgBox("Teen")
Case 18 To 55
MsgBox("Adult")
Case Else
MsgBox("Senior")
End Select
End Sub
End Module
Consider the following program: Module Exercise
Public Function Main() As Integer
Dim Number As Short
Number = 448
Select Case Number
Case -602
MsgBox("-602")
Case 24
MsgBox("24")
Case 0
MsgBox("0")
End Select
Return 0
End Function
End Module
Obviously this Select Case statement will work in rare cases where the expression of a case exactly matches the value sought for. In reality, for this type of scenario, you could validate a range of values. The Visual Basic language provides an alternative. You can check whether the value of the Expression responds to a criterion instead of an exact value. To create it, you use the Is operator with the following formula: Is Operator Value You start with the Is keyword. It is followed by one of the Boolean operators we saw in the previous lessons: =, <>, <, <=, >, or >=. On the right side of the boolean operator, type the desired value. Here are examples: Module Exercise
Public Function Main() As Integer
Dim Number As Short
Number = -448
Select Case Number
Case Is < 0
MsgBox("The number is negative")
Case Is > 0
MsgBox("The number is positive")
Case Else
MsgBox("0")
End Select
Return 0
End Function
End Module
Although we used a natural number here, you can use any appropriate logical comparison that can produce a True or a False result. You can also combine it with the other alternatives we saw previously, such as separating the expressions of a case with commas.
With the Select...Case statement, we saw how to check different values against a central one and take action when one of those matches the tag. Here is an example: Module Exercise
Public Function Main() As Integer
Dim Number As UShort, MembershipType As String
Number = 2
Select Case Number
Case 1
MembershipType = "Teen"
Case 2
MembershipType = "Adult"
Case Else
MembershipType = "Senior"
End Select
MsgBox("Membership Type: " & MembershipType)
Return 0
End Function
End Module
We also saw that the Visual Basic language provides the Choose() function that can check a condition and take an action. The Choose() function is another alternative to a Select...Case statement. Once again, consider the syntax of the Choose function: Public Function Choose( _ ByVal Index As Double, _ ByVal ParamArray Choice() As Object _ ) As Object This function takes two required arguments. The first argument is equivalent to the Expression of our Select Case formula. As mentioned already, the first argument must be a number (a Byte, an SByte, a Short, a UShort, an Integer, a UInteger, a Long, a ULong, a Single, a Double, or a Decimal value). This is the central value against which the other values will be compared. Instead of using Case sections, provide the equivalent ExpressionX values as a list of values in place of the second argument. The values are separated by commas. Here is an example: Choose(Number, "Teen", "Adult", "Senior") As mentioned already, the values of the second argument are provided as a list. Each member of the list uses an index. The first member of the list, which is the second argument of this function, has an index of 1. The second value of the argument, which is the third argument of the function, has an index of 2. You can continue adding the values of the second argument as you see fit. When the Choose() function has been called, it returns a value of type Object. You can retrieve that value, store it in a variable and use it as you see fit. Here is an example: Module Exercise
Public Function Main() As Integer
Dim Number As UShort, MembershipType As String
Number = 1
MembershipType = Choose(Number, "Teen", "Adult", "Senior")
MsgBox("Membership Type: " & MembershipType)
Return 0
End Function
End Module
|
|
|||||||||||||||||||||||||||
|
|
||||||||||||||||||||||||||||
Practical
Learning: Using a Select...Case Condition
